Contenuto

# Funzione STILE

Applica uno stile alla cella che contiene la formula. Dopo un determinato periodo di tempo, può essere applicato un altro stile.

Questa funzione restituisce sempre il valore numerico 0, che consente di essere usato aggiungendo la funzione STILE ad altre funzioni nella stessa cella senza modificarne il loro valore.

La funzione STILE non dovrebbe essere utilizzata senza una valida ragione; il suo scopo è quello di affiancare le funzioni aggiuntive asincrone per segnalare in modo visibile la presenza di un determinato risultato. In quasi tutti gli altri casi, la formattazione condizionale rappresenta un'alternativa migliore.

### Sintassi

STILE("Stile" [; Tempo [; "Stile2"]])

Stile è il nome dello stile di cella da applicare alla cella. I nomi degli stili non fanno distinzione tra minuscole e maiuscole e devono essere inseriti tra virgolette.

Tempo è un intervallo di tempo opzionale espresso in secondi. Una volta trascorso questo tempo, viene applicato lo stile definito in Stile2. Lasciare vuoto questo parametro se non si desidera che lo stile venga modificato.

Stile2 è il nome opzionale di uno stile di cella da assegnare alla cella una volta trascorso il periodo specificato nel parametro Tempo. Se questo parametro è mancante viene applicato lo stile di cella "Predefinito".

Nelle funzioni di LibreOffice Calc, i parametri contrassegnati come "opzionali" possono essere tralasciati solo se non sono seguiti da altri parametri. Ad esempio, in una funzione con quattro parametri in cui gli ultimi due sono contrassegnati come "opzionali", è possibile tralasciare il parametro 4 oppure i parametri 3 e 4, ma non il solo parametro 3.

### Esempi

=10+STILE("Buono",60,"Neutro")

Inserisce il valore 10 nella cella e applica lo stile "Buono". Trascorsi 60 secondi, viene applicato lo stile "Neutro".

=A1*A2+STILE(SE(ATTUALE()<100,"Non buono","Buono"))

Inserisce il risultato della moltiplicazione dei valori delle celle A1 e A2 e applica lo stile "Non buono" se il risultato è inferiore a 100, altrimenti viene applicato lo stile "Buono". In questo caso la funzione ATTUALE() è usata per ottenere la valutazione del valore corrente della funzione nella cella.

="Totale"&T(STILE("Risultato"))

Inserisce il testo "Totale" nella cella e applica lo stile "Risultato". Da notare che questo esempio tratta valori testuali, perciò il risultato della funzione STILE necessita di essere concatenato al testo usando l'operatore &. La funzione T() viene utilizzata per evitare che il numero "0" sia concatenato al testo risultante.

#### Informazioni tecniche

Questa funzione non fa parte dello standard Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format. Lo spazio dei nomi è

ORG.OPENOFFICE.STYLE

Argomenti correlati

Pagina wiki relativa a STILE (in inglese).

Funzioni del foglio elettronico

Assegnazione di formati mediante formule

Funzione ATTUALE

Funzione T